Clear the memory, or, kill all the variable definitions

kill( all ) ;

C:\Users\manto\Documents\201819_esami\PAOM\20190307_PAOM\ladder_frame_0.png

C:\Users\manto\Documents\201819_esami\PAOM\20190307_PAOM\ladder_frame.png

equilibrium equations for the quarter
(simplified) ladder frame chassis

eqtX : UA = 0 ;

eqtY : VD = 0 ;

eqtZ : WA + WD - F = 0;

eqrOX : - F * c + WD * b + ThetaD = 0;

eqrOY : PhiA - WA*a + F*a = 0;

eqrOZ : 0 = 0 ;

define a list of equations and a list of unknowns

eqlst : [ eqtX  , eqtY  , eqtZ ,
          eqrOX , eqrOY , eqrOZ ] ;

unlst : [ UA , WA , PhiA , VD , WD, ThetaD ];

solve the linear system of equations

linsolve( eqlst , unlst ) ;

there is one dependent equation, so I'm unable to solve 
the problem of obtaining all the reaction forces/moments by equilibrium alone

unlst_red : [ UA , WA , PhiA , VD , WD];

Solution of the system of linear equation and assignemtn to the variables in one step.
linsolve(eqn,[x_1,..x_n]), globalsolve = true;

linsolve( eqlst , unlst_red ) , globalsolve = true ;

we now define the cross section resultants for the D->B beam, 
as a function of the s = 0 ... a arclength coordinate
directions x and y constitute an in-section reference system.

traslation equilibrium along direction z 
N:0;
traslation equilibrium along direction x and y
Sx and Sy are the shear forces acting at the shear center (Point C)
Sx: -VD;
Sy: -WD;
N acts at the centroid of section (Point G)

N  :  0 $

Sx : -VD;

Sy : -WD;

equilibrium with respect to rotation along the (G,x) axis

linsolve(Mfx + WD * s = 0, Mfx ), globalsolve = true ;

linsolve(Mfy - VD * s = 0, Mfy ), globalsolve = true ;

torque must be evaluated by the equilibrium along the axis z at the shear center.

linsolve(Mt + ThetaD - WD * e = 0, Mt), globalsolve = true ;

we now evaluate the internal strain energy for the DB beam
Kt coincides with Jp for circular or hollowed circular cross-section. 

U : integrate ( 
               ( 
                       Jyy * Mfy^2
                   +   Jxx * Mfx^2
                   + 2*J12 * Mfx*Mfy
                )/( 
                    2*E*(Jxx*Jyy-Jxy^2)
                )/bnd_m_stiffmult
            +
                N^2/2/E/A  /nrm_f_stiffmult
            +
                ( 
                      chix   * Sx^2
                    + chiy   * Sy^2
                    + chixy  * Sx * Sy
                )/(
                    2*G*A
                ) /shr_f_stiffmult
            +
                Mt^2 / 2 / G/ ( Kt )  /trs_m_stiffmult
 , s , 0 , a );

The strain energy is now known as a quadratic function of F and ThetaD
We recur to the Castigliano's second theorem to obtain the rotation at D, 
component x

thetaD : diff( U , ThetaD )   ;

we now force that rotation to be zero in order to reinstate the kinematic
compatibility with respect to the skew-symmetry constraint acting in D.

linsolve ( thetaD = 0 , ThetaD ) , globalsolve = true;

I now redefine the internal strain energy as a function of F alone,
i.e. I now force a substitution of the expression above within U

U : ev( U )$

We employ Castigliano theorem again to obtain the deflection of
the quarter ladder frame chassis at the application point of the external
force F

delta : diff( U , F )$

we now evaluate from delta the torsional stiffness (ts) of the chassis;
the deflection delta of the whole chassis, supported at three
wheel centers and loaded at the fourth, is four times delta.

ts : fullratsimp(
 (F * (2*c)^2) / ( 4 * delta )
) ;

Channel section dimensions:
_h : web heigth, measured at the thin wall midsurface
_b : wing width, measured at the thin midsurface
_t : web and wing wall thickness
(e,f) : Gx,Gy position of the shear center, with respect to the center of gravity
(m,n) : Ox,Oy position of the center of gravity, with respect to the web midpoint
upsilon: _b/_h
epsilon: _t/_h
Chassis dimensions:
a   : half wheelbase
b   : half the distance between the profiles
c   : half the axle track

dim : 
[
    a=1200,
    b=400-m,
    c=600,
    _h=80         * _h_mult,
    upsilon=40/80,
    epsilon=6/80  * _t_mult / _h_mult
],_t_mult=1,_h_mult=1;

mat : 
[
    G  = 210000 / 2 / (1 +3/10),
    E  = 210000,
    nu = 3/10    
];

sec :
[
    A       = 2*epsilon*_h^2*upsilon+epsilon*_h^2,
    Jxx     =(epsilon*_h^4+6*epsilon*_h^4*upsilon)/12,
    Jyy     =(2*epsilon*_h^4*upsilon^3+epsilon*_h^4*upsilon^4)/(6*upsilon+3),
    Jxy     =0,
    Kt      =(epsilon^3*_h^3*(_h+2*_h*upsilon))/3,
    chix    =(15+78*upsilon+138*upsilon^2+96*upsilon^3+24*upsilon^4)/(20*upsilon^4+80*upsilon^3+80*upsilon^2),
    chiy    =(6+72*upsilon+300*upsilon^2+480*upsilon^3+240*upsilon^4)/(180*upsilon^2+60*upsilon+5),
    chixy   =0,
    e       = (4*_h*upsilon^2+12*_h*upsilon^3)/(12*upsilon^2+8*upsilon+1),
    f       = 0,
    m       = (_h*upsilon^2)/(2*upsilon+1),
    n       = 0
],dim;

Evaluate the torsional stiffness of the ladder frame for this specific dimensioning and material. 

ev(ts, [dim]), infeval, numer;

myts : ev(ts, [dim, mat, sec]), infeval, numer;

refts : ev(myts, bnd_m_stiffmult=1,shr_f_stiffmult=1,trs_m_stiffmult=1);

I consider the section bending and shear stiffness to vanish, i.e. the torsional stiffness
of the profile is left alone in elastically connecting the two rigid bodies

myts$
ev( % , trs_m_stiffmult=1)$
limit(%, bnd_m_stiffmult, 0)$
limit(%, shr_f_stiffmult, 0);
%/refts;

a residual stiffness of the 7.2% of the actual one is obtained.

I consider the torsional stiffness to vanish, while maintaining 
both the shear and the bending stiffness unchanged.

myts$
ev(%, bnd_m_stiffmult=1)$
ev(%, shr_f_stiffmult=1)$
limit( % , trs_m_stiffmult,0);
%/refts;

a residual stiffness of the 92.8%=100%-7.2% of the actual one is obtained.

I consider the torsional stiffness to vanish, while
case 1) maintaining the bending stiffness unaltered, with vanishing shear stiffness
case 2) maintaining the shear stiffness unaltered, with vanishing bending stiffness

myts$
ev(%, bnd_m_stiffmult=1)$
limit( % , shr_f_stiffmult,0)$
limit( % , trs_m_stiffmult,0);
%/refts;

myts$
ev(%, shr_f_stiffmult=1)$
limit( % , bnd_m_stiffmult,0)$
limit( % , trs_m_stiffmult,0);
%/refts;

no residual stiffness for the structure is obtained 
if the bending and the shear stiffness of the profiles acts alone.

moreover, if only one amongst the bending and the shear stiffness vanish 
no further stiffening is observed with respect to the torsion alone

myts$
ev( % , trs_m_stiffmult=1)$
ev( % , bnd_m_stiffmult=1)$
limit( % , shr_f_stiffmult,0);
%/refts;

myts$
ev( % , trs_m_stiffmult=1)$
ev(%, shr_f_stiffmult=1)$
limit( % , bnd_m_stiffmult,0);
%/refts;

summarizing the results, we obtain the following table

trs | bnd | shr | residual stiffness
 1  |  1  |  1  | 100. %
 1  |  1  |  0  |   7.2%
 1  |  0  |  1  |   7.2%
 1  |  0  |  0  |   7.2%
 0  |  1  |  1  |  92.8%
 0  |  1  |  0  |   0.0%
 0  |  0  |  1  |   0.0%
 0  |  0  |  0  |   0.0%

which may be rationalized according to the following scheme